Types.td

Go to the documentation of this file.

//===-- Types.td -------------------------------------------*- tablegen -*-===//
//
// Part of the LLZK Project, under the Apache License v2.0.
// See LICENSE.txt for license information.
// Copyright 2025 Veridise Inc.
// SPDX-License-Identifier: Apache-2.0
//
//===----------------------------------------------------------------------===//
 
#ifndef LLZK_FELT_TYPES
#define LLZK_FELT_TYPES
 
include "llzk/Dialect/Felt/IR/Dialect.td"
 
include "mlir/IR/AttrTypeBase.td"
include "mlir/IR/BuiltinTypes.td"
include "mlir/IR/BuiltinTypeInterfaces.td"
include "mlir/Interfaces/MemorySlotInterfaces.td"
 
def LLZK_FeltType : TypeDef<FeltDialect, "Felt"> {
  let mnemonic = "type";
  let summary = "finite field element";
  let description = [{
    An element of a finite field. The field can be specified (e.g., !felt.type<"bn254">)
    or left unspecified (!felt.type), to be filled in by the backend consumer of LLZK IR.
    Leaving the field unspecified may reduce the power of certain transformation passes.
 
    For a field with prime modulus `p`, a felt denotes a residue modulo `p`, with its
    canonical representative in `[0, p)`. An unreduced integer representation does not
    denote a distinct value outside this range.
 
    Backends are responsible for performing conversions between felts of different
    fields. If a circuit needs to encode translations between fields, the circuit
    may define a function prototype, e.g.:
 
    ```llzk
    function.def @convert(%a : !felt.type<"bn254">) -> !felt.type<"goldilocks">;
    ```
 
    and perform the lowering of calls to this conversion function in a
    backend-specific manner.
 
    The field name can be chosen from one of the built-in fields or specified using
    `felt.field` specification attributes on the root module.
  }];
 
  let parameters = (ins OptionalParameter<"::mlir::StringAttr">:$fieldName);
 
  let assemblyFormat = "(`<` $fieldName^ `>`)?";
 
  // Default when omitted: felt.type with no fieldName
  let builderCall = "::llzk::felt::FeltType::get($_builder.getContext())";
 
  let builders = [
      // Like the default builder but with null for the optional field name.
      AttrBuilder<(ins), [{ return $_get(context, ::mlir::StringAttr()); }]>,
      AttrBuilder<
          (ins "::llvm::StringRef":$fieldName),
          [{ return $_get(context, ::mlir::StringAttr::get(context, fieldName)); }]>];
 
  let extraClassDeclaration = [{
    bool hasField() const {
      auto name = getFieldName();
      return name && !name.empty();
    }
 
    const ::llzk::Field &getField() const;
  }];
 
  let genVerifyDecl = 1;
}
 
#endif // LLZK_FELT_TYPES